add valkey

flake.nix

@@ -3,9 +3,9 @@
 
   inputs = { };
 
-  outputs =
+  outputs = _: {
-    { ... }:
+    lib = {
-    {
       mkLib = pkgs: import ./lib.nix { inherit pkgs; };
     };
+  };
 }

lib.nix

@@ -1,6 +1,7 @@
 { pkgs }:
 let
   inherit (pkgs) lib;
+  runtime = ".compose";
 in
 {
   mkWrapper =
@@ -8,8 +9,10 @@ in
       config,
       name,
       enableTui ? false,
+      modules ? [ ],
     }:
     let
+      merged_config = lib.foldl' (acc: elem: lib.recursiveUpdate acc elem) config modules;
       removeNullAndEmptyAttrs =
         attrs:
         let
@@ -29,7 +32,7 @@ in
         };
       configFile = toPCJson name (
         removeNullAndEmptyAttrs (
-          config
+          merged_config
           // {
             is_tui_disabled = !enableTui;
           }
@@ -39,8 +42,12 @@ in
     pkgs.writeShellApplication {
       inherit name;
       text = ''
-        PC_CONFIG_FILES=${configFile} ${pkgs.process-compose}/bin/process-compose "$@"
 
+
+        PC_NO_SERVER=true PC_CONFIG_FILES=${configFile} RUNTIME_PATH=$(pwd)/${runtime} ${pkgs.process-compose}/bin/process-compose "$@"
       '';
     };
+  mkPostgres = import ./services/postgres.nix { inherit pkgs; };
+  mkRedis = import ./services/redis.nix { inherit pkgs; };
+  mkValkey = import ./services/valkey.nix { inherit pkgs; };
 }

services/postgres.nix

@@ -0,0 +1,152 @@
+{
+  pkgs,
+}:
+let
+  inherit (pkgs) lib;
+in
+{
+  name,
+  default_config ? true,
+  config ? { },
+  extra_config ? '''',
+  package ? pkgs.postgresql,
+  port ? 5432,
+  bind ? "localhost",
+  initialDatabases ? [ ],
+  ...
+}:
+let
+  merged_config =
+    (
+      if default_config then
+        {
+          listen_addresses = "localhost";
+          port = 5432;
+          shared_buffers = "128MB";
+          work_mem = "4MB";
+          logging_collector = false;
+
+        }
+      else
+        { }
+    )
+    // config
+    // {
+      unix_socket_directories = ".";
+      listen_addresses = bind;
+      inherit port;
+    };
+  toStr =
+    value:
+    if true == value then
+      "yes"
+    else if false == value then
+      "no"
+    else if lib.isString value then
+      "'${lib.replaceStrings [ "'" ] [ "''" ] value}'"
+    else
+      builtins.toString value;
+  configFile = pkgs.writeTextFile {
+    name = "postgresql.conf";
+    text =
+      lib.concatStringsSep "\n" (
+        lib.mapAttrsToList (n: v: "${n} = ${toStr v}") (
+          lib.filterAttrs (lib.const (x: x != null)) merged_config
+        )
+      )
+      + extra_config;
+  };
+  setupInitialDatabases =
+    if initialDatabases != [ ] then
+      (lib.concatMapStrings (db: ''
+        echo "Checking presence of database ${db.name}"
+        dbAlreadyExists="$(echo "SELECT 1 AS result FROM pg_database WHERE datname='${db.name}';" | psql --dbname postgres | ${pkgs.gnugrep}/bin/grep -c 'exists = "1"' || true)"
+        echo "$dbAlreadyExists"
+        if [ 1 -ne "$dbAlreadyExists" ]; then
+          echo "Creating database ${db.name}"
+          echo 'CREATE DATABASE "${db.name}";' | psql --dbname postgres
+          ${lib.optionalString (db.user != null && db.password != null) ''
+            echo "Creating user ${db.user}"
+            psql --dbname postgres <<'EOF'
+            DO $$
+              BEGIN
+                CREATE ROLE "${db.user}" WITH LOGIN PASSWORD '${db.password}';
+                EXCEPTION WHEN duplicate_object THEN RAISE NOTICE '%, skipping', SQLERRM USING ERRCODE = SQLSTATE;
+              END
+            $$;
+            GRANT ALL PRIVILEGES ON DATABASE "${db.name}" TO "${db.user}";
+            \c ${db.name}
+            GRANT ALL PRIVILEGES ON SCHEMA public TO "${db.user}";
+            EOF
+          ''}
+        else
+          echo "Database ${db.name} already exists"
+        fi
+      '') initialDatabases)
+    else
+      "";
+  setupScript = pkgs.writeShellApplication {
+    name = "setup-postgres";
+    runtimeInputs = [
+      package
+      pkgs.coreutils
+    ];
+    text = ''
+      POSTGRES_RUN_INITIAL_SCRIPT="false"
+      if [[ ! -d "$PGDATA" ]]; then
+        initdb --no-instructions
+        POSTGRES_RUN_INITIAL_SCRIPT="true"
+        echo
+        echo "PostgreSQL initdb process completed"
+        echo
+      fi
+      cp ${configFile} "$PGDATA"/postgresql.conf
+      if [[ "$POSTGRES_RUN_INITIAL_SCRIPT" == "true" ]]; then
+        echo
+        echo "PostgreSQL is setting up the initial database"
+        echo
+        pg_ctl -w start -o "-c listen_addresses= -p ${builtins.toString port}"
+        ${setupInitialDatabases}
+        pg_ctl -m fast -w stop
+      else 
+        echo
+        echo "Database directory exists. Skipping initialization"
+        echo
+      fi
+      unset POSTGRES_RUN_INITIAL_SCRIPT
+    '';
+  };
+
+  script = pkgs.writeShellApplication {
+    name = "run-postgres";
+    text = ''
+      set -euo pipefail
+      PGDATA=$RUNTIME_PATH/${name}
+      PGHOST=$RUNTIME_PATH/${name}
+      PGPORT=${builtins.toString port}
+      echo "Starting postgres with PGDATA=''${PGDATA} PGHOST=''${PGHOST} PGPORT=''${PGPORT}"
+      export PGDATA PGHOST PGPORT
+      ${setupScript}/bin/setup-postgres
+      ${package}/bin/postgres
+    '';
+  };
+in
+# configFileCheck = pkgs.runCommand {} ''
+#     ${package}/bin/postgres -D${configFile} -C config_file
+#     touch $out
+#   '';
+{
+  processes."${name}" = {
+    command = "${script}/bin/run-postgres";
+    shutdown.signal = 2;
+    readiness_probe = {
+      exec.command = "${package}/bin/pg_isready -h ${bind} -p ${builtins.toString port} -d postgres";
+      initial_delay_seconds = 2;
+      period_seconds = 10;
+      timeout_seconds = 4;
+      success_threshold = 1;
+      failure_threshold = 5;
+    };
+    availability.restart = "on_failure";
+  };
+}

services/redis.nix

@@ -0,0 +1,73 @@
+{
+  pkgs,
+}:
+let
+  inherit (pkgs) lib;
+in
+{
+  name,
+  default_config ? true,
+  extra_config ? '''',
+  package ? pkgs.redis,
+  port ? 6379,
+  bind ? "localhost",
+  ...
+}:
+
+let
+
+  generateRedisConfig = ''
+    cat > "$RUNTIME_PATH"/${name}.conf <<EOF
+    ${lib.optionalString default_config ''
+      port ${builtins.toString port}
+      ${lib.optionalString (bind != null) "bind ${bind}"}
+      ${lib.optionalString (port == 0) "unixsocket \"$RUNTIME_PATH/${name}.sock\""}
+      ${lib.optionalString (port == 0) "unixsocketperm 700"}
+    ''}
+    ${extra_config}
+    EOF
+  '';
+
+  script = pkgs.writeShellApplication {
+    name = "run-redis";
+    text = ''
+      set -euo pipefail
+      REDISDATA="$RUNTIME_PATH"/${name}/
+      ${
+        if (port == 0) then
+          ''
+            REDIS_UNIX_SOCKET = "$RUNTIME_PATH"/${name}.sock
+            export REDIS_UNIX_SOCKET
+            echo "Starting redis on unix socket ''${REDIS_UNIX_SOCKET}"
+          ''
+        else
+          ''
+            echo "Starting redis on port ${builtins.toString port}"
+          ''
+      }
+      export REDISDATA
+      if [ ! -d "$REDISDATA" ]; then
+        mkdir -p "$REDISDATA"
+      fi
+      ${generateRedisConfig}
+      ${package}/bin/redis-server "$RUNTIME_PATH"/${name}.conf --daemonize no --dir "$REDISDATA"
+    '';
+  };
+  tcpPing = "${package}/bin/redis-cli -p ${builtins.toString port} ping";
+  unixPing = "${package}/bin/redis-cli -s \"$RUNTIME_PATH\"/${name}.sock ping";
+in
+{
+  processes."${name}" = {
+    command = "${script}/bin/run-redis";
+    readiness_probe = {
+      exec.command = if port == 0 then unixPing else tcpPing;
+      initial_delay_seconds = 2;
+      period_seconds = 10;
+      timeout_seconds = 4;
+      success_threshold = 1;
+      failure_threshold = 3;
+    };
+    availability.restart = "on_failure";
+  };
+
+}

services/valkey.nix

@@ -0,0 +1,73 @@
+{
+  pkgs,
+}:
+let
+  inherit (pkgs) lib;
+in
+{
+  name,
+  default_config ? true,
+  extra_config ? '''',
+  package ? pkgs.valkey,
+  port ? 6379,
+  bind ? "localhost",
+  ...
+}:
+
+let
+
+  generateValkeyConfig = ''
+    cat > "$RUNTIME_PATH"/${name}.conf <<EOF
+    ${lib.optionalString default_config ''
+      port ${builtins.toString port}
+      ${lib.optionalString (bind != null) "bind ${bind}"}
+      ${lib.optionalString (port == 0) "unixsocket \"$RUNTIME_PATH/${name}.sock\""}
+      ${lib.optionalString (port == 0) "unixsocketperm 700"}
+    ''}
+    ${extra_config}
+    EOF
+  '';
+
+  script = pkgs.writeShellApplication {
+    name = "run-valkey";
+    text = ''
+      set -euo pipefail
+      VALKEYDATA="$RUNTIME_PATH"/${name}/
+      ${
+        if (port == 0) then
+          ''
+            VALKEY_UNIX_SOCKET = "$RUNTIME_PATH"/${name}.sock
+            exportVALKEY_UNIX_SOCKET
+            echo "Starting valkey on unix socket ''${VALKEY_UNIX_SOCKET}"
+          ''
+        else
+          ''
+            echo "Starting valkey on port ${builtins.toString port}"
+          ''
+      }
+      export VALKEYDATA
+      if [ ! -d "$VALKEYDATA" ]; then
+        mkdir -p "$VALKEYDATA"
+      fi
+      ${generateValkeyConfig}
+      ${package}/bin/valkey-server "$RUNTIME_PATH"/${name}.conf --daemonize no --dir "$VALKEYDATA"
+    '';
+  };
+  tcpPing = "${package}/bin/valkey-cli -p ${builtins.toString port} ping";
+  unixPing = "${package}/bin/valkey-cli -s \"$RUNTIME_PATH\"/${name}.sock ping";
+in
+{
+  processes."${name}" = {
+    command = "${script}/bin/run-valkey";
+    readiness_probe = {
+      exec.command = if port == 0 then unixPing else tcpPing;
+      initial_delay_seconds = 2;
+      period_seconds = 10;
+      timeout_seconds = 4;
+      success_threshold = 1;
+      failure_threshold = 3;
+    };
+    availability.restart = "on_failure";
+  };
+
+}