feat: add neovide-nightly

2026-04-02 21:41:06 +02:00
parent 18b15f1539
commit 7190efff26
7 changed files with 4629 additions and 51 deletions
@@ -0,0 +1,134 @@
+{
+  lib,
+  rustPlatform,
+  clangStdenv,
+  fetchFromGitHub,
+  linkFarm,
+  fetchgit,
+  runCommand,
+  gn,
+  neovim,
+  ninja,
+  makeWrapper,
+  pkg-config,
+  python3,
+  removeReferencesTo,
+  cctools,
+  SDL2,
+  fontconfig,
+  libxrandr,
+  libxi,
+  libxext,
+  libxcursor,
+  libx11,
+  stdenv,
+  libglvnd,
+  libxkbcommon,
+  enableWayland ? stdenv.hostPlatform.isLinux,
+  wayland,
+  callPackage,
+}: let
+  sources = callPackage ../../../../_sources/generated.nix {};
+  inherit (sources.neovide) src;
+in
+  rustPlatform.buildRustPackage.override {stdenv = clangStdenv;} (finalAttrs: {
+    pname = "neovide";
+    version = src.rev;
+    src = src;
+
+    cargoLock = sources.neovide.cargoLock."Cargo.lock";
+
+    env = {
+      SKIA_SOURCE_DIR = let
+        repo = fetchFromGitHub {
+          owner = "rust-skia";
+          repo = "skia";
+          # see rust-skia:skia-bindings/Cargo.toml#package.metadata skia
+          tag = "m145-0.92.0";
+          hash = "sha256-9N780AwheKBJRcZC4l/uWFNq+oOyoNp4M6dJAVVAFeo=";
+        };
+        # The externals for skia are taken from skia/DEPS
+        externals = linkFarm "skia-externals" (
+          lib.mapAttrsToList (name: value: {
+            inherit name;
+            path = fetchgit value;
+          }) (lib.importJSON ./skia-externals.json)
+        );
+      in
+        runCommand "source" {} ''
+          cp -R ${repo} $out
+          chmod -R +w $out
+          ln -s ${externals} $out/third_party/externals
+        '';
+
+      SKIA_GN_COMMAND = "${gn}/bin/gn";
+      SKIA_NINJA_COMMAND = "${ninja}/bin/ninja";
+    };
+
+    nativeBuildInputs =
+      [
+        makeWrapper
+        pkg-config
+        python3 # skia
+        removeReferencesTo
+      ]
+      ++ lib.optionals stdenv.hostPlatform.isDarwin [
+        cctools.libtool
+      ];
+
+    nativeCheckInputs = [neovim];
+
+    buildInputs = [
+      SDL2
+      fontconfig
+      rustPlatform.bindgenHook
+    ];
+
+    postFixup = let
+      libPath = lib.makeLibraryPath (
+        [
+          libglvnd
+          libxkbcommon
+          libx11
+          libxcursor
+          libxext
+          libxrandr
+          libxi
+        ]
+        ++ lib.optionals enableWayland [wayland]
+      );
+    in ''
+      # library skia embeds the path to its sources
+      remove-references-to -t "$SKIA_SOURCE_DIR" \
+        $out/bin/neovide
+
+      wrapProgram $out/bin/neovide \
+        --prefix LD_LIBRARY_PATH : ${libPath}
+    '';
+
+    postInstall =
+      lib.optionalString stdenv.hostPlatform.isDarwin ''
+        mkdir -p $out/Applications
+        cp -r extra/osx/Neovide.app $out/Applications
+        ln -s $out/bin $out/Applications/Neovide.app/Contents/MacOS
+      ''
+      + lib.optionalString stdenv.hostPlatform.isLinux ''
+        for n in 16x16 32x32 48x48 256x256; do
+          install -m444 -D "assets/neovide-$n.png" \
+            "$out/share/icons/hicolor/$n/apps/neovide.png"
+        done
+        install -m444 -Dt $out/share/icons/hicolor/scalable/apps assets/neovide.svg
+        install -m444 -Dt $out/share/applications assets/neovide.desktop
+      '';
+
+    disallowedReferences = [finalAttrs.env.SKIA_SOURCE_DIR];
+
+    meta = {
+      description = "Simple, no-nonsense, cross-platform graphical user interface for Neovim";
+      mainProgram = "neovide";
+      homepage = "https://neovide.dev/";
+      changelog = "https://github.com/neovide/neovide/releases/tag/${finalAttrs.version}";
+      license = lib.licenses.mit;
+      platforms = lib.platforms.unix;
+    };
+  })
@@ -0,0 +1,37 @@
+{
+  "expat": {
+    "url": "https://chromium.googlesource.com/external/github.com/libexpat/libexpat.git",
+    "rev": "8e49998f003d693213b538ef765814c7d21abada",
+    "sha256": "sha256-zP2kiB4nyLi0/I8OsRhxKG0qRGPe2ALLQ+HHfqlBJ6Y="
+  },
+  "libjpeg-turbo": {
+    "url": "https://chromium.googlesource.com/chromium/deps/libjpeg_turbo.git",
+    "rev": "e14cbfaa85529d47f9f55b0f104a579c1061f9ad",
+    "sha256": "sha256-Ig+tmprZDvlf/M72/DTar2pbxat9ZElgSqdXdoM0lPs="
+  },
+  "icu": {
+    "url": "https://chromium.googlesource.com/chromium/deps/icu.git",
+    "rev": "364118a1d9da24bb5b770ac3d762ac144d6da5a4",
+    "sha256": "sha256-frsmwYMiFixEULsE91x5+p98DvkyC0s0fNupqjoRnvg="
+  },
+  "zlib": {
+    "url": "https://chromium.googlesource.com/chromium/src/third_party/zlib",
+    "rev": "646b7f569718921d7d4b5b8e22572ff6c76f2596",
+    "sha256": "sha256-jNj6SuTZ5/a7crtYhxW3Q/TlfRMNMfYIVxDlr7bYdzQ="
+  },
+  "harfbuzz": {
+    "url": "https://chromium.googlesource.com/external/github.com/harfbuzz/harfbuzz.git",
+    "rev": "31695252eb6ed25096893aec7f848889dad874bc",
+    "sha256": "sha256-Csyz08JTNXfY2fo27x1Eg1CqO/tt8Rt9udr3KflojSg="
+  },
+  "wuffs": {
+    "url": "https://skia.googlesource.com/external/github.com/google/wuffs-mirror-release-c.git",
+    "rev": "e3f919ccfe3ef542cfc983a82146070258fb57f8",
+    "sha256": "sha256-373d2F/STcgCHEq+PO+SCHrKVOo6uO1rqqwRN5eeBCw="
+  },
+  "libpng": {
+    "url": "https://skia.googlesource.com/third_party/libpng.git",
+    "rev": "4e3f57d50f552841550a36eabbb3fbcecacb7750",
+    "sha256": "sha256-tNRrA9RUp6Mi7dbIB/70a/4tn/JxAsTUb9EI9nlXLjM="
+  }
+}