{
  description = "Build a cargo project without extra checks";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane.url = "github:ipetkov/crane";

    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      crane,
      flake-utils,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        inherit (pkgs) lib;

        craneLib = crane.mkLib pkgs;

        # Common arguments can be set here to avoid repeating them later
        # Note: changes here will rebuild all dependency crates
        commonArgs = {
          src = craneLib.cleanCargoSource ./.;
          strictDeps = true;

          buildInputs =
            [ ]
            ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
              pkgs.libiconv
            ];
        };

        fileSetForCrate =
          crate:
          lib.fileset.toSource {
            root = ./.;
            fileset = lib.fileset.unions [
              ./Cargo.toml
              ./Cargo.lock
              (craneLib.fileset.commonCargoSources ./crates/entity)
              (craneLib.fileset.commonCargoSources ./crates/migration)
              (craneLib.fileset.commonCargoSources ./crates/server)
              (craneLib.fileset.commonCargoSources crate)
            ];
          };

        rtmp-to-whip-simple-server = craneLib.buildPackage (
          commonArgs
          // {
            pname = "rtmp-to-whip";
            version = "0.1.0";
            cargoArtifacts = craneLib.buildDepsOnly commonArgs;
            cargoExtraArgs = "-p server";
            src = fileSetForCrate ./crates/server;
          }
        );

      in
      {
        checks = {
          inherit rtmp-to-whip-simple-server;
        };

        packages.default = rtmp-to-whip-simple-server;

        apps.default = flake-utils.lib.mkApp {
          drv = rtmp-to-whip-simple-server;
        };

        devShells.default = craneLib.devShell {
          checks = self.checks.${system};

          ADMIN_REF_CODE = "meowmeowpurrrmeow";

          packages = [
            pkgs.clang
            pkgs.mold
            pkgs.sea-orm-cli
            pkgs.cmake
            pkgs.opus
            pkgs.pkgconf
            pkgs.just
          ];
        };
      }
    );
}