{
  pkgs,
  lib,
  inputs,
  system,
  ...
}:
let
  youtube-music = (
    final: prev: {
      youtube-music = prev.youtube-music.overrideAttrs (old: rec {
        pname = "youtube-music";
        version = "3a7d3ff73";
        src = prev.fetchFromGitHub {
          owner = "pear-devs";
          repo = "pear-desktop";
          rev = "3a7d3ff73de49fcf7e7051dd1bdf450db4b222bf";
          sha256 = "sha256-Q/E37HzQR2Ghxs8vV7WNCXn+DqIhpjhY3SoW3OMITTs=";
        };
        postPatch =
          let
            patch = prev.fetchurl {
              url = "https://github.com/pear-devs/pear-desktop/commit/25fccc9a62044ca7006f271a6a2520724e5720e1.patch";
              hash = "sha256-WAiaqsWlOXyv7FRlvM0LUY17dwCI8BQsQdO1M4zYg7k=";
            };
          in
          ''
            ${prev.git}/bin/git apply -R -p1 < ${patch}
          '';
        pnpmDeps = prev.pnpm.fetchDeps {
          inherit pname version src;
          fetcherVersion = 2;
          hash = "sha256-9arC2c92U2tILFCBIRcGo9iNaPbNefDDfR9lGaSS88E=";
        };
      });

    }
  );
  pkgs_gamescope = import inputs.nixpkgs-gamescope {
    inherit system;
    config = {
      allow_unfree = true;
    };
  };
  gamescope_overlay = self: super: {
    gamescope =
      pkgs_gamescope.callPackage "${inputs.nixpkgs-gamescope}/pkgs/by-name/ga/gamescope/package.nix"
        { };
  };
in
{
  nixpkgs.overlays = [
    gamescope_overlay
    youtube-music
  ];
}